發布日期：2017/7/13

 Function getHTTPPage(url) 'Asp 獲取遠程網頁內容實例代碼
  dim http
  set http=Server.createobject("Microsoft.XMLHTTP")'建立XMLHTTP對象
  Http.open "GET",url,false '設置http對象打開體例 GET體例，URL[連接頁面地址]，同步處理
  Http.send() '發送請求
  if Http.readystate<>4 then'對象處理狀況為 非結束
     exit function '退出函數
  end if
  getHTTPPage=bytesToBSTR(Http.responseBody,"gb2312")'BytesToBstr獲取的源碼轉換為中文的代碼
  set http=nothing '消滅對象
  if err.number<>0 then err.Clear  '消滅錯誤
 End function

'==================================================
'函數名：BytesToBstr
'作 用：將獲取的源碼轉換為中文
'參 數：Body ------要轉換的變量
'參 數：Cset ------要轉換的類型
'==================================================   
 Function BytesToBstr(body,Cset)'BytesToBstr獲取的源碼轉換為響應的代碼
  dim objstream
  set objstream = Server.CreateObject("adodb.stream")
  objstream.Type = 1
  objstream.Mode =3
  objstream.Open
  objstream.Write body
  objstream.Position = 0
  objstream.Type = 2
  objstream.Charset = Cset
  BytesToBstr = objstream.ReadText
  objstream.Close
  set objstream = nothing
 End Function